Saya ketik =round di sel Excel, lalu muncul empat pilihan sekaligus: ROUND, ROUNDDOWN, ROUNDUP, dan MROUND. Semuanya sama-sama rumus untuk pembulatan, saya penasaran apa bedanya empat rumus itu.
Ternyata ketika saya browsing, rumus pembulatan Excel jumlahnya lebih dari empat itu. Saya hitung ada dua belas fungsi yang tugasnya membulatkan angka, tidak semua berawalan kata ROUND. Semuanya saya coba satu per satu di laptop saya.
Pembahasan akan saya mulai dari salah satu hal terpenting dalam penggunaan rumus Excel, yaitu: angka dan argumennya dipisah pakai koma atau titik koma?
Titik koma atau koma, tergantung pada pengaturan wilayah di Windows
Excel pada laptop saya berbahasa Inggris. Bisa juga terlihat dari nama fungsinya yang tertulis ROUND, bukan bahasa Indonesia, dan keterangannya pun berbahasa Inggris. Tapi rumusnya harus ditulis pakai titik koma, =ROUND(2,567;2).
Penyebabnya, ada dua pengaturan yang terpisah. Nama fungsi mengikuti bahasa Excel. Tanda pemisah mengikuti wilayah Windows. Saya cek pengaturan wilayah di laptop saya, hasilnya seperti ini:
- Wilayah: Indonesia, dengan bahasa tampilan Inggris
- Pemisah daftar: titik koma
- Tanda desimal: koma
- Pemisah ribuan: titik
Di Indonesia, koma sudah dipakai untuk desimal, seperti 2,5 kilogram. Kalau koma juga dipakai untuk memisahkan argumen, Excel tidak bisa membedakan 2,5 itu satu angka atau dua angka. Maka pemisahnya diganti titik koma.
Ini juga menjawab soal titik dua. Titik dua bukan pemisah argumen sama sekali. Tugasnya menandai rentang sel, misalnya A1:A10 yang berarti dari A1 sampai A10. Tanda ini sama di semua wilayah.
| Tanda | Contoh | Artinya |
|---|---|---|
| ; | =ROUND(A1;2) | Pemisah antar argumen |
| , | 2,567 | Tanda desimal |
| . | 1.234 | Pemisah ribuan |
| : | A1:A10 | Rentang sel |
Saya coba sengaja gunakan tanda yang salah untuk tahu apa yang terjadi. Saya ketik =ROUND(A1,2) langsung ditolak Excel. Saya ketik =ROUND(2.567;2), dengan titik sebagai desimal, juga ditolak. Yang diterima dan tulisannya benar adalah =ROUND(A1;2) dan =ROUND(2,567;2).
Mungkin Anda bertanya, bagaimana jika kita mengirim file yang sudah menggunakan pengaturan rumus dari laptop kita ke orang yang pengaturan laptopnya berbeda? Jawabannya adalah, rumus yang kita ketik dengan titik koma ternyata disimpan Excel di dalam berkasnya dengan format bakunya sendiri, yaitu pakai koma dan titik. Jadi kalau berkas itu saya kirim ke orang yang Excelnya berpengaturan Amerika, rumusnya otomatis tampil pakai koma di layar dia, dan hasilnya tetap sama. Rumusnya tidak rusak di jalan.
Yang perlu diwaspadai justru jika kita hanya menyalin rumusnya. Misalkan, dari tutorial berbahasa Inggris, saya menempelkannya ke sel di Excel laptop saya yang pengaturan wilayahnya Indonesia, biasanya muncul pesan seperti pada gambar di atas. Tapi tidak selalu. Saya coba tempel =SUM(1,5), maksudnya menjumlahkan 1 dan 5. Excel menerimanya tanpa pesan apa pun, lalu membacanya sebagai satu angka, yaitu 1,5. Hasilnya salah tanpa peringatan, dan ini lebih berbahaya daripada pesan galat. Karena itu, sebelum menempelkan rumus dari tutorial berbahasa Inggris, ganti dulu semua komanya jadi titik koma.
Membaca petunjuk yang muncul di bawah rumus
Begitu Anda mengetik =ROUND( lengkap dengan kurung bukanya, Excel menampilkan kotak kecil di bawah sel. Isinya kurang lebih ROUND(number; num_digits). Ini bukan hiasan. Kotak itu adalah daftar petunjuk untuk isian rumusnya, berurutan dari kiri ke kanan.
Pada kasus seperti foto saya di atas, cara bacanya begini:
- number adalah angka yang mau dibulatkan. Bisa angka langsung, bisa alamat sel seperti A1.
- num_digits adalah jumlah angka di belakang koma yang mau disisakan.
- Bagian yang dicetak tebal adalah isian yang sedang Anda ketik saat itu. Begitu Anda mengetik titik koma, tebalnya pindah ke isian berikutnya.
- Isian di dalam kurung siku, misalnya
[num_digits]pada TRUNC, artinya boleh dikosongkan. Kalau dikosongkan, Excel memakai nilai bawaannya.
ROUND, ROUNDUP, dan ROUNDDOWN
Tiga ini keluarga yang sama. Semuanya meminta dua isian, angka dan jumlah digit. Bedanya hanya arah pembulatannya.
- ROUND membulatkan biasa, seperti yang diajarkan di sekolah. Lima ke atas naik, di bawah lima turun.
- ROUNDUP selalu naik, berapa pun sisanya.
- ROUNDDOWN selalu turun, berapa pun sisanya.
| Rumus | Hasil |
|---|---|
=ROUND(2,567;2) | 2,57 |
=ROUND(2,567;1) | 2,6 |
=ROUND(2,567;0) | 3 |
=ROUNDUP(2,521;1) | 2,6 |
=ROUNDDOWN(2,589;1) | 2,5 |
Perhatikan dua baris terakhir. Angka 2,521 cuma lebih 0,021 dari 2,5, tapi ROUNDUP tetap menaikkannya ke 2,6. Sebaliknya 2,589 sudah hampir 2,6, tapi ROUNDDOWN tetap menurunkannya ke 2,5. Itulah gunanya dua fungsi ini: arahnya pasti, tidak peduli sisanya.
Isian jumlah digit juga boleh minus. Angka minus artinya membulatkan ke sebelah kiri koma, jadi ke puluhan, ratusan, atau ribuan. =ROUND(1234,5;-2) menghasilkan 1.200, sedangkan =ROUNDUP(1234,5;-2) menghasilkan 1.300. Ini berguna untuk membulatkan harga atau anggaran ke ratusan rupiah.
MROUND, CEILING, dan FLOOR untuk kelipatan
Kadang yang dibutuhkan bukan jumlah digit, melainkan kelipatan. Misalnya harga harus berakhir di kelipatan Rp500 karena kembaliannya tidak ada uang receh. Untuk itu ada tiga fungsi, dan isian keduanya adalah kelipatannya.
| Rumus | Hasil |
|---|---|
=MROUND(12340;500) | 12.500 |
=CEILING(12340;500) | 12.500 |
=FLOOR(12340;500) | 12.000 |
=CEILING.MATH(12340;1000) | 13.000 |
=FLOOR.MATH(12340;1000) | 12.000 |
MROUND mencari kelipatan yang paling dekat. Angka 12.340 lebih dekat ke 12.500 daripada ke 12.000, jadi hasilnya 12.500. Saya juga mencoba angka yang tepat di tengah, 12.250, dan MROUND memilih naik ke 12.500.
CEILING selalu naik ke kelipatan berikutnya, FLOOR selalu turun. Pasangannya mirip ROUNDUP dan ROUNDDOWN, hanya saja patokannya kelipatan, bukan digit.
CEILING.MATH dan FLOOR.MATH adalah versi yang lebih baru. Bedanya yang paling terasa ada dua. Isian kelipatannya boleh dikosongkan, dan kalau dikosongkan dianggap 1. Hasil keduanya pada angka negatif saya tunjukkan di bagian jebakan di bawah.
INT, TRUNC, EVEN, dan ODD
Empat fungsi ini paling jarang dibahas, padahal dua di antaranya sering dipakai tanpa sadar.
- INT membuang desimal dan turun ke bilangan bulat di bawahnya.
=INT(7,89)menghasilkan 7. - TRUNC memotong desimal begitu saja tanpa membulatkan.
=TRUNC(7,89)juga 7. Bedanya, TRUNC bisa menyisakan sebagian desimal:=TRUNC(7,89;1)menghasilkan 7,8, bukan 7,9. - EVEN naik ke bilangan genap berikutnya.
=EVEN(7,89)menghasilkan 8. - ODD naik ke bilangan ganjil berikutnya.
=ODD(7,89)menghasilkan 9.
Untuk angka positif, INT dan TRUNC tampak kembar. Mereka baru kelihatan berbeda begitu angkanya negatif.
Jebakan angka negatif
Saya masukkan angka 2,5 dan -2,5 ke semua fungsi tadi, lalu membandingkan hasilnya.
| Fungsi | 2,5 | -2,5 |
|---|---|---|
| ROUND | 3 | -3 |
| ROUNDUP | 3 | -3 |
| ROUNDDOWN | 2 | -2 |
| INT | 2 | -3 |
| TRUNC | 2 | -2 |
| CEILING.MATH | 3 | -2 |
| FLOOR.MATH | 2 | -3 |
| EVEN | 4 | -4 |
| ODD | 3 | -3 |
| MROUND, kelipatan 1 | 3 | #NUM! |
Ada tiga hal yang perlu dicatat dari tabel ini.
ROUNDUP pada -2,5 menghasilkan -3, padahal -3 itu lebih kecil. Kedengarannya aneh untuk fungsi bernama “up”. Dokumentasi Microsoft sendiri menjelaskan ROUNDUP sebagai membulatkan menjauhi nol, dan ROUNDDOWN sebagai mendekati nol. Jadi “naik” dan “turun” di sini bukan soal besar kecil, melainkan soal jauh dekat dari nol.
INT dan TRUNC berpisah jalan. INT pada -2,5 turun ke -3, karena INT selalu menuju bilangan bulat yang lebih kecil. TRUNC cuma memotong desimalnya, jadi -2. Kalau Anda pernah memakai INT untuk membuang desimal pada data yang ada angka minusnya, misalnya selisih atau kerugian, hasilnya bisa meleset satu angka tanpa terasa.
MROUND menolak angka negatif dengan kelipatan positif. =MROUND(-2,5;1) langsung mengeluarkan #NUM!. Angka dan kelipatannya harus bertanda sama. Kalau angkanya negatif, kelipatannya juga ditulis negatif.
Jebakan format sel: hanya tampilannya yang dibulatkan
Ini yang paling sering terjadi, dan pelakunya bukan rumus sama sekali. Banyak orang membulatkan dengan tombol pengurang desimal di tab Home. Angkanya memang tampil lebih pendek, tapi nilai aslinya tidak berubah.
Saya buktikan dengan tiga sel yang isinya sama, 1,004. Ketiganya saya format supaya tampil dua desimal, jadi di layar terbaca 1,00, 1,00, dan 1,00. Lalu saya jumlahkan. Hasilnya tampil 3,01.
Satu tambah satu tambah satu jadi 3,01. Bagi siapa pun yang membaca laporan itu, angkanya terlihat salah hitung. Padahal Excel tidak salah. Yang dijumlahkan adalah nilai aslinya, 1,004 tiga kali, yaitu 3,012, lalu ditampilkan dua desimal jadi 3,01.
Di kolom sebelahnya, setiap sel saya bulatkan dulu dengan =ROUND(A4;2). Nilainya benar-benar jadi 1,00, dan jumlahnya 3,00. Pas dengan yang terlihat.
Patokan saya sekarang: kalau angkanya cuma untuk dilihat, format sel sudah cukup. Kalau angkanya akan dihitung lagi, dijumlah, dikalikan, atau dicocokkan dengan nota, bulatkan dengan rumus.
Menentukan akan pakai rumus yang mana untuk kasus yang mana
Setelah mencoba semua rumus pembulatan Excel tadi, saya ringkaskan untuk Anda menjadi pertanyaan yang perlu dijawab sebelum memilih.
- Mau membulatkan biasa ke sekian desimal? ROUND.
- Arahnya harus pasti naik atau pasti turun, misalnya menghitung kebutuhan bahan yang tidak boleh kurang? ROUNDUP atau ROUNDDOWN.
- Harus jatuh di kelipatan tertentu, seperti Rp500 atau Rp1.000? MROUND untuk yang terdekat, CEILING.MATH atau FLOOR.MATH kalau arahnya harus pasti.
- Cuma mau membuang desimal? TRUNC. Pakai INT hanya kalau Anda memang ingin angka negatif ikut turun.
- Butuh bilangan genap atau ganjil? EVEN atau ODD.
Penjelasan lengkap tiap fungsi ada di dokumentasi resmi Microsoft untuk fungsi ROUND, yang juga menautkan ke fungsi pembulatan lainnya.